Batch Ping-Dauertest mit Mail-Versand

Batch Kommandozeilen Snippets

Aus dem vorherigen Beitrag könntet Ihr noch das Batch Script für den Ping-Dauertest kennen. Ich habe dieses Script jetzt mit einem Mailversand erweitert. Voraussetzung ist, dass ihr einen Mailserver und eine Mailadresse habt, über die die Nachricht versendet werden kann. Den Mailversand selbst erledige ich mit Hilfe des Kommandozeilen-Tools „BLAT“ – welches es hier gibt.

Das bisherige Script wurde um zwei weitere Zeilen erweitert.

@echo off
rem Ping-Dauertest mit Log und Mailversand
rem www.JoeKaDev.de

set iphost=127.0.0.1

title --- Ping-Dauertest --- JoeKaDev.de --- Schreibe Log Datei ... %IPHOST%


set logdatei=pinglog-%iphost%.log
echo Ping Dauertest -- Start am %date% um %time% auf IP/Host: %iphost%
echo status; host; datum; time >> %logdatei%

set status=0
set status_off=1

:dauertest
ping %iphost% -n 2 -4 | find "TTL=" >NUL:
set status=%errorlevel%
if not %status%==%status_off% (
  set status_off=%status%
  if %status%==0 (
    echo online; %iphost% ; %date% ; %time%  >> %logdatei%
    echo [ONLiNE] IP/Host: %iphost% am %date% um %time% 
    blat.exe -to empfaenger@mailserver.de -f dauerping@mailserver.de -server mail.mailserver.de -s "[ONLiNE] %iphost%" -body "%logdatei%" -attacht "pinglog-%iphost%.log" >NUL
  ) else (
  echo offline; %iphost% ; %date% ; %time% >> %logdatei%
  echo [OFFLiNE] IP/Host: %iphost% am %date% um %time% 
  blat.exe -to empfaenger@mailserver.de -f dauerping@mailserver.de -server mail.mailserver.de -s "[OFFLiNE] %iphost%" -body "%logdatei%" -attacht "pinglog-%iphost%.log" >NUL
    )
)
goto :dauertest

Wichtig ist, dass das Tool BLAT mit in dem Verzeichnis des Scriptes liegt. Sonst funktioniert der Mailversand wahrscheinlich nicht.

Kurze Erläuterung zu den von mir genutzten BLAT Switches

-to Empfänger-Adresse

-f Absender-Adresse

-u Benutzername (optional)

-p Passwort (optional)

-server Adresse des Mailservers

-s „Betreff der Nachricht“

-body „Text der Nachricht“

-attacht Datei oder Verzeichnis zu einer Datei die angehängt werden soll (optional)

Wer weitere Konfigurationen für den Mailversand benötigt, erhält über den Kommandozeilenaufruf „blat.exe /?“ eine Übersicht aller möglichen Varianten.

In meinem Beispiel enthält die Nachricht einen passenden Betreff (Online oder Offline) und im Nachrichtentext wird direkt das wiedergegeben, was auch in die Log-Datei eingetragen wird. Zusätzlich wird noch die aktuelle Log-Datei angehängt und mit versand. So sollte man immer alle wichtigen Meldungen im Postfach haben.

Schreibe einen Kommentar

Deine E-Mail-Adresse wird nicht veröffentlicht. Erforderliche Felder sind mit * markiert.