Hardwareinventarisierung mittels Batch Script

Batch Kommandozeilen Snippets

Heute mal ein kurzes Script zur einfachen Hardwareinventarisierung in einem Netzwerk. Dieses Script kann in das normale Active-Directory Login eingebunden werden. Es liest den Hostnamen, Systemhersteller, Modelname, Seriennummer, Betriebssystem inkl. Service Pack, die Speichergröße von Laufwerk C: und die RAM Größe aus und schreibt dies in eine Textdatei, benannt nach dem Hostnamen, die in dem Scriptordner abgelegt wird.

 

Das Script für die Hardwareinventarisierung

@echo off
cls
title Host-Info-Collector v1.0 --- www.JoeKaDev.de ---
echo Sammle Informationen von %computername% ...
echo.
set system=
set hersteller=
set model=
set seriennummer=
set osname=
set servicepack=
setlocal ENABLEDELAYEDEXPANSION
set "volume=C:"
set totalRAM=
set availableRAM=
set usedRAM=
set IPv4=
set Domain=
for /F "tokens=2 delims='='" %%A in ('wmic OS Get csname /value') do set system=%%A
for /F "tokens=2 delims='='" %%A in ('wmic ComputerSystem Get Manufacturer /value') do set hersteller=%%A
for /F "tokens=2 delims='='" %%A in ('wmic ComputerSystem Get Model /value') do set model=%%A
for /F "tokens=2 delims='='" %%A in ('wmic Bios Get SerialNumber /value') do set seriennummer=%%A
for /F "tokens=2 delims='='" %%A in ('wmic os get Name /value') do set osname=%%A
for /F "tokens=1 delims='|'" %%A in ("%osname%") do set osname=%%A
for /F "tokens=2 delims='='" %%A in ('wmic os get ServicePackMajorVersion /value') do set servicepack=%%A
for /F "tokens=4" %%a in ('systeminfo ^| findstr physikalischer') do if defined totalRAM (set availableRAM=%%a) else (set totalRAM=%%a)
set totalRAM=%totalRAM:,0%
set availableRAM=%availableRAM:,0%
set /a usedRAM=totalRAM-availableRAM
for /f "tokens=1*delims=:" %%i IN ('fsutil volume diskfree %volume%') DO (
    set "diskfree=!disktotal!"
    set "disktotal=!diskavailable!"
    set "diskavailable=%%j"
)
for /f "tokens=1,2" %%i IN ("%disktotal% %diskavailable%") DO set "disktotal=%%i"& set "diskavailable=%%j"
echo Fertig!
set file="%~dp0%computername%.txt"
echo -------------------------------------------- >> %file%
echo System Name: %system% >> %file%
echo Hersteller: %hersteller% >> %file%
echo Model: %model% >> %file%
echo Seriennummer: %seriennummer% >> %file%
echo Betriebssystem: %osname% >> %file%
echo Service Pack: %servicepack% >> %file%
echo CPU: %processor_architecture% >> %file%
echo Speicher C:\ Total: %disktotal:~0,-9% GB >> %file%
echo Speicher C:\ Verfuegbar: %diskavailable:~0,-9% GB >> %file%
echo RAM Total: %totalRAM% >> %file%
echo RAM Verfuegbar: %usedRAM% >> %file%
echo -------------------------------------------- >> %file%
pause

 

Schreibe einen Kommentar

Deine E-Mail-Adresse wird nicht veröffentlicht. Erforderliche Felder sind mit * markiert.